ஓப்பன் ஆஃபிஸ் பேஸிக்-100

முந்தைய தொடரில் கூறியவாறு  தோன்றிடும் காலியான வரைகலை பதிப்பு திரையின் இடதுபுறமுள்ள கருவிகளின் பட்டியலிலிருந்துControlsஎன்ற உருவ பொத்தானை தெரிவுசெய்து சொடுக்கி ஒரு கட்டுபாட்டு பெட்டியை உருவாக்கிஅதற்கு internet graphic wizard என்றவாறு ஒரு பெயரிட்டிடுக. அவ்வாறே திரையின் இடதுபுறமுள்ள கருவிகளின் பட்டியலிலிருந்துlabelஎன்ற உருவ பொத்தானை தெரிவுசெய்து சொடுக்கி ஒரு கட்டுபாட்டு பெட்டியை உருவாக்கிஅதற்கு Select graphic no என்றவாறு ஒரு பெயரிட்டிடுக

   பின்னர் அதே கருவி பட்டியில் உள்ள  File Selectionஎன்றவாறு உள்ள உருவ பொத்தானை தெரிவுசெய்து பிடித்து கொண்டு முதலில் நீளம் அகலம்  எவ்வளவு இருக்கவேண்டும் என தீர்மாணித்துகொண்டு அதன்பின்னர் ஒரு செவ்வக தேடிடும் பெட்டியை(browse) வரைந்திடுக .பிறகு பண்பியல்பு(properties) எனும் உருவபொத்தானை தெரிவுசெய்து சொடுக்குக  உடன் பண்பியல்பு(properties) எனும் உரையாடல் பெட்டி திரையில் தோன்றிடும்  அதில் இந்த உரையாடல் பெட்டிக்கு பெயராக  தேடிடும்பெட்டி(browse) என்றும்  இதர பண்பியல்புகளையும் அமைத்துகொண்டு Ok என்ற பொத்தானை தெரிவுசெய்து சொடுக்குக பின்னர் திரையின் இடதுபுறமுள்ள கருவிகளின் பட்டியலிலிருந்து பொத்தான்(button)  என்ற உருவ பொத்தானை தெரிவுசெய்து சொடுக்கி << Back ,Next>>, Finish, Cancel ஆகிய பொத்தான்களையும் மேலே கூறியவாறு அதனதன் பண்பியல்பு உரையாடல்  பெட்டியையும் (படம்-100-1) தோன்றசெய்து இவைகளுக்கான பெயரையும் இதர பண்பியல்புகளையும் அமைத்துகொள்க 

படம்-100-1

 இவ்வாறு இந்த பொத்தான்களையும் பெட்டிகளையும் உருவாக்கிடும்போது திரையானது வடிவமைப்பு நிலைக்கு மாறியமையும் அந்நிலையில்   கருவிகளின் பட்டியலிலிருந்துActivate Test Mode என்றவாறு உள்ள உருவ பொத்தானை தெரிவுசெய்து பிடித்து கொண்டு ஒவ்வொன்றையும் செயல்படுகின்றதாவென பரிசோதித்து (test)சரிபார்த்து கொள்க. உண்மையில் இந்த பொத்தான்கள் நாம் உருவாக்கிடும் உரையாடல் பெட்டியில்  செயல்படுமாறு செய்திடவேண்டும் அதற்காக ஒவ்வொரு பொத்தானையும் செயல்படுத்துவதற்குநாம் உருவாக்கிய Module1என்பதை அதற்கான தாவியின் திரையை தோன்ற செய்து பின்வரும் கட்டளைவரிகளை  தவறில்லாமல் உள்ளீடு செய்து இணைத்திடுக

Private oDialog as Variant ' private, module-wide variable

Sub RunGraphicsWizard

oDialog = createUnoDialog(DialogLibraries.Standard.Dialog1)

oDialog.execute

End Sub

Sub CancelGraphicsDialog

oDialog.endExecute()

End Sub

Sub FinishGraphicsDialog

Dim sFile as String, sGraphicURL as String

oDialog.endExecute()

sFile = oDialog.Model.FileControl1.Text

' the FileControl contains a system path, we have to transform it to a file URL

' We use the built-in Basic runtime function ConvertToURL for this purpose

sGraphicURL = ConvertToURL(sFile)

' insert the graphics

' access the document model

oDoc = ThisComponent

' get the Text service of the document

oText = oDoc.getText()

' create an instance of a graphic object using the document service factory

oGraphicObject = oDoc.createInstance("com.sun.star.text.GraphicObject")

' set the URL of the graphic

oGraphicObject.GraphicURL = sGraphicURL

' get the current cursor position in the GUI and create a text cursor from it

oViewCursor = oDoc.getCurrentController().getViewCursor()

oCursor = oText.createTextCursorByRange(oViewCursor.getStart())

' insert the graphical object at the cursor position

oText.insertTextContent(oCursor.getStart(), oGraphicObject, false)

End Sub

Sub Main

...

End Sub

 உதாரணமாக நாம் உருவாக்கிடும்internet graphic wizard  என்ற உரையாடல் பெட்டியிலுள்ள Cancel எனும் பொத்தானை தெரிவுசெய்து கொண்டு  இதற்கான பண்பியல்பு(properties) எனும் உரையாடல் பெட்டி திரையில் தோன்றசெய்க அதில்Event  என்ற தாவியின் திரையை தோன்றிட செய்க இதில் when initiating  எனஅபதற்கருகில் உள்ள முப்புள்ளியை தெரிவுசெய்து சொடுக்குக

படம்-100-2

 உடன்Assign Action என்ற  மற்றொரு உரையாடல் பெட்டி தோன்றிடும் இதில் Macro  எனும் பொத்தானை தெரிவுசெய்து சொடுக்கியவுடன்  Macro Selector   என்ற  மற்றொரு உரையாடல் பெட்டி(படம்-100-2) தோன்றிடும் இந்த உரையாடல் பெட்டியில் FirstStepsBasic.Standard.Module1, என்பதை தேடிபிடித்திடுக  Sub CancelGraphicsDialog என்பதை தெரிவுசெய்து கொண்டுokஎன்ற பொத்தானை தெரிவுசெய்து சொடுக்குக அவ்வாறே Assign Action என்ற  உரையாடல் பெட்டியிலுள்ள  okஎன்ற பொத்தானையும்  தெரிவுசெய்து சொடுக்குக  உடன் நாம் உருவாக்கிடும் internet graphic wizard  என்ற உரையாடல் பெட்டியிலுள்ள Cancel எனும் பொத்தானை செயல்படுத்திடுவதற்கான கட்டளைவரி இணைக்கபட்டுவிடும்

பிறகு திரையின் இடதுபுறமுள்ள கருவிகளின் பட்டியலிலிருந்துRunஎன்ற உருவ பொத்தானை தெரிவுசெய்து சொடுக்கி நாம் உருவாக்கிடும் internet graphic wizard  என்ற உரையாடல் பெட்டியிலுள்ள Finish,Cancel ஆகிய  பொத்தான்கள் உண்மையில் செயல்படுகின்றதாவென சரிபார்த்திடுக. இப்போது நாம் உருவாக்கிடும் உரையாடல் பெட்டியின் செயலை வரிசை படுத்திடுதற்கானAutoPilotஎன்ற இரு பக்கமுடைய உரையாடல் பெட்டியில் அமைப்பதற்கானஇறுதி நிலைக்கு வந்திருக்கின்றோம் 

படம்-100-3

முதலில்Control  என்ற விசையை அழுத்தி பிடித்துகொண்டுfile control  என்பதை தெரிவுசெய்து கொண்டு properties என்ற உரையாடல் பெட்டியில்  page(step) என்ற  பண்பியல்பை 1 என அமைத்து கொண்டு உள்ளீட்டு விசையை தெரிவுசெய்து சொடுக்குக  பின்னர் நாம் உருவாக்கிடும் உரையாடல் பெட்டியின் விளிம்பை தெரிவுசெய்து பிடித்துகொண்டு properties என்ற உரையாடல் பெட்டியில்page(step)என்ற  பண்பியல்பை 2  என அமைத்து கொண்டு உள்ளீட்டு விசையை தெரிவுசெய்து சொடுக்குக இப்போது நாம் உருவாக்கிய Anchor என்ற தலைப்பில்at paragraph at character ஆகிய பொத்தான்கள்(படம்-100-3) மட்டும் தெரியும் at aragraph என்பது இயல்பு நிலையில் தெரிவுசெய்து இருந்திடுமாறும் தேவையென தெரிவுசெய்தால் மட்டும் at character  எனும் பொத்தான் தெரிவுசெய்திடுமாறும் பண்பியல்பு பெட்டிஉரையால் பெட்டியில் page(step)என்ற  பண்பியல்பை 2  என அமைத்து கொண்டு உள்ளீட்டு விசையை தெரிவுசெய்து சொடுக்குக  page(step) என்ற  பண்பியல்பை 1  என அமைத்து முந்தைய தொடக்கநிலைக்கு சென்றிடுமாறு அமைத்துகொள்க

 நாம் உருவாக்கிடும்internet graphic wizard  என்ற உரையாடல் பெட்டியிலுள்ள << Back ,Next>>, ஆகிய பொத்தான்களுக்கும் page(step) என்பதை அமைத்திட இந்த AutoPilotஎன்ற இருபக்கஉரையாடல்  பெட்டியை விரிவு படுத்தி பின்வரும் கட்டளைவரிகளை தவறில்லாமல் உள்ளீடு செய்திடுக

Sub BackGraphicsDialog

oDialog.Model.Step = 1

oDialog.Model.Back.Enabled = false

oDialog.Model.Next.Enabled = true

End Sub

Sub NextGraphicsDialog

oDialog.Model.Step = 2

oDialog.Model.Back.Enabled = true

oDialog.Model.Next.Enabled = false

End Sub

Sub FinishGraphicsDialog

Dim sGraphicURL as String, iAnchor as Long

oDialog.endExecute()

sFile = oDialog.Model.FileControl1.Text

' State = Selected corresponds to 1 in the API

if oDialog.Model.AsCharacter.State = 1 then

iAnchor = com.sun.star.text.TextContentAnchorType.AS_CHARACTER

elseif oDialog.Model.AtParagraph.State = 1 then

iAnchor = com.sun.star.text.TextContentAnchorType.AT_PARAGRAPH

endif

' the File Selection control returns a system path, we have to transform it to a File URL

' We use the built-in Basic runtime function ConvertToURL for this purpose

sGraphicURL = ConvertToURL(sFile)

' access the document model

oDoc = ThisComponent

' get the Text service of the document

oText = oDoc.getText()

' create an instance of a graphic object using the document service factory

oGraphicObject = oDoc.createInstance("com.sun.star.text.GraphicObject")

' set the URL of the graphic

oGraphicObject.GraphicURL = sGraphicURL

oGraphicObject.AnchorType = iAnchor

' get the current cursor position in the GUI and create a text cursor from it

oViewCursor = oDoc.getCurrentController().getViewCursor()

oCursor = oText.createTextCursorByRange(oViewCursor.getStart())

' insert the graphical object at the beginning of the text

oText.insertTextContent(oCursor.getStart(), oGraphicObject, false)

End Sub